[Axe] Automates cellulaires I : les explosions

[Persalteas]

CET ARTICLE EST UN ENTIER PLAGIAT DE CELUI CI FAIT PAR MATREF. Mon seul mérite là dedans est la traduction HTML>BBCode.

Salut les gens !

Ici je vais vous apprendre comment faire des explosions en Axe. Je ne vous cache pas que je me suis grandement inspiré du tuto en Anglais d'Omnimaga par leafiness0, mais c'est pas une traduction que je vous propose ici.

Donc, pour faire une explosion, le principe est de connaître exactement les coordonnées de tous les pixels de votre effet.

Pour cela on va utiliser une aire libre de la RAM, disons L1, et on va y stocker les coordonnées de tous les pixels qu'on va utiliser (qui représenteront autant de particules).

Prenez ça comme un grand tableau unidimensionnel : un objet (donc un pixel) s'étend sur 4 aires :

• Coordonnée X
• Coordonnée Y
• Vitesse X
• Vitesse Y

Mais comme les modifications qu'on va y faire sont de l'ordre du centième, et comme l'Axe ne permet pas de manipuler des valeurs aussi petites, on va tout multiplier par 256 à l'initialisation, changer les valeurs comme il faut et afficher en redivisant par 256. On a donc besoin de valeurs 2 octets.

On a donc ce code de base :

Code: Tout sélectionner

:.EXP
:.Pour 80 particules
:For(A,0,79)
:.4 éléments de 2 octets chacun
:
:48*256→{A*8+L1→r6}r
:32*256→{r6+2}r
:rand^300-150→{r6+4}r
:rand^300-350→{r6+6}r
:End

Voilà, L1 est initialisée ! Le premier champ est le X de départ * 256 (toutes les particules explosent du même point), le deuxième champ le Y de départ * 256, le troisième champ la vitesse X, entre -150 et 149, pour que la particule puisse aller aussi bien à gauche qu'à droite, et le quatrième champ la vitesse Y, entre -350 et -51, pour que le pixel monte un peu avant de retomber.

Maintenant, on va modifier les coordonnées de chacun de ces pixels simplement en :

1. Sélectionnant chaque pixel
2. Ajoutant la vitesse X à la position X
3. Ajoutant un offset à la vitesse Y (qui simulera la gravité)
4. Ajoutant la vitesse Y à la position Y

Et on aura plus qu'à afficher un pixel en divisant les coordonnées par 256 ! C'est pas plus dur que ça !

Code: Tout sélectionner

:.EXP
:.Pour 80 particules
:For(A,0,79)
:.4 éléments de 2 octets chacun
:
:48*256→{A*8+L1→r6}r
:32*256→{r6+2}r
:rand^300-150→{r6+4}r
:rand^300-350→{r6+6}r
:End
:
:Repeat getKey(15)
:
:For(A,0,79)
:A*8+L1→r6
:
:.On ajoute vX à X
:{r6}r+{r6+4}r→{r6}r
:.vY + gravité
:{r6+6}r+6→{r6+6}r
:.vY + Y
:{r6+2}r+{r6+6}r→{r6+2}r
:
:.Affichage du pixel
:Pxl-On({r6}r/256,{r6+2}r/256
:End
:DispGraphClrDraw
:End

Et voici le résultat :



Vous pouvez changer l'envergure de l'explosion en changeant les deux premiers champs et la gravité appliquée au quatrième

Bonne programmation !