Ici, je vais vous montrer comment faire défiler UNE image 96*64 d'un bout à l'autre de l'écran pour donner l'impression d'un paysage défilant.
Prenons une image quelconque :
Et faisons-la défiler à l'écran, disons de droite à gauche !
Le manière de procéder est simple :
- Au tout début, on affiche l'image sur l'écran
- On entre dans la boucle principale (comme un Repeat getkey)
- On copie la toute première colonne de pixels dans une zone libre
- On décale l'écran à gauche : une ligne blanche apparaît à droite
- On recopie la colonne précédemment sauvegardée tout à droite
En pratique, c'est pas beaucoup plus dur, commençons par l'initialisation :
- Code: Tout sélectionner
:.SCROLL
:.Absorption de l'image
:[Pic1]→Pic1
:
:.On copie l'image à l'écran sans la dernière ligne
:Copy(Pic1,L6,756
:
:Repeat getKey(15)
:
:End
Maintenant on va pouvoir entrer dans le vif du sujet.
En premier : copier la première colonne de l'écran. On va pour cela copier l'état du premier bit de chaque ligne, avec 0 = pixel éteint et 1 = pixel allumé. Sachant que chaque ligne a 96 pixels, 96 pixels / 8 bits = 12, donc une ligne est représentée par 12 octets. Ce qui signifie que pour passer à la colonne suivante, il faut progresser par bonds de 12 octets.
Pour trouver l'état d'un bit, on utilise la commande EXPeBIT. Le e est la constante d'Euler, qu'on obtient avec [2nd]+[÷]. EXP est l'expression dont le bit doit être testé, et BIT le numéro du bit entre 0 et 7.
Attention cependant : normalement, on compte les bits de droite à gauche, avec le premier représenté par 7 et le dernier par 0. En Axe, c'est l'inverse ! Le premier est 0 et le dernier 7.
On peut donc trouver l'état du bit de chaque ligne de l'écran (sauf la denière) avec une simple boucle For. Mais cet état, il faut le stocker quelque part, donc prenons L1 comme aire libre :
- Code: Tout sélectionner
:Repeat getKey(15)
:For(r1,0,62
:{r1*12+L6}e0→{r1+L1
:End
Ici, chaque premier bit de chaque colonne de l'écran est enregistré dans L1. Maintenant, on décale l'écran avec Horizontal - et on passe à la dernière étape, recopier le contenu de L1 à la toute droite de l'écran.
À ce point, on a L6 avec notre image affichée avec une colonne blanche à droite et L1 pleine de 0 et de 1 sur 64 octets (et pas bits !). Pour recopier notre colonne sortante à droite, il faut activer ou désactiver ses bits selon le contenu de L1, mais sans toucher aux autres bits ! Alors nous devons utiliser OR, qui ne peut qu'activer des bits et pas les désactiver !
- Code: Tout sélectionner
:Horizontal -
:For(r1,0,62
:.On ajoute 11 octets pour arriver à droite
:{r1+L1} or {r1*12+11+L6}→{r1*12+11+L6
:End
:DispGraph
:End
Notez que cette grosse ligne moche peut être optimisée en :
- Code: Tout sélectionner
:{r1+L1} or {r1*12+11+L6→r2}→{r2
Ensuite on affiche L6, mais surtout on ne l'efface pas avec ClrDraw, parce qu'à aucun moment on ne redessine l'image !
Résultat :
- Code: Tout sélectionner
:.SCROLVER
:[Pic1]→Pic1
:
:Copy(Pic1,L6,756
:
:Repeat getKey(15)
:For(r1,0,62
:{r1*12+L6}→{r1+L1
:End
:Horizontal -
:For(r1,0,62
:{r1+L1} or {r1*12+11+L6→r2}→{r2
:End
:DispGraph
:End
C'est aussi simple que ça !
Pour faire un scrolling en des sens différents, la technique est la même : pour scroller de gauche à droite, il faut remplacer Horizontal - par Horizontal + et copier la dernière ligne vers la première. Pour cela, il faut faire {r1*12+11+L6}e7, le multiplier par 128 pour déplacer le bit vers la toute gauche et utiliser OR sur {r1*11+L6}.
Par contre, pour scroller de haut en bas ou de bas en haut, la technique n'est pas la même :
- Au lieu de copier le dernier bit de chaque douzième octet, on copie carrément les douze premiers octets (ou derniers) et on utilise → à la place de OR
- On remplace Horizontal par Vertical
Ceci dit, ça reste pas trop compliqué
Voici le code pour un scrolling de bas en haut :- Code: Tout sélectionner
:.SCROLVER
:[Pic1]→Pic1
:
:Copy(Pic1,L6,756
:
:Repeat getKey(15)
:For(r1,0,11
:{r1+L6}→{r1+L1
:End
:Vertical -
:For(r1,0,11
:{r1+L1}→{r1+L6+744
:End
:DispGraph
:End
Le scrolling vertical est même largement plus simple que le scrolling horizontal !
Vous pouvez faire des choses plus poussées par exemple en faisant réagir le sens du scrolling avec la pression des flèches, ou même faire scroller une image dans deux sens à la fois !
