Tower Def

[Plokki]

oui c'est vrai que "plusieurs heures" est exagéré mais bref: la flemme

[Plokki]

Voilà le code source:

_theta_TOWER.8xp

J"aimerais juste savoir s'il y a des optimisations que je pourrais facilement faire mais sinon le jeu est finit en lui-même.
Je voudrais aussi savoir comment mettre le titre/la description qu'on voit apparaître avec mirage os dans le menu de sélection du programme en bas.

[Plokki]

Bon ben j'en déduis que mon code est irréprochable
Je suis juste un peu déçu de ne pas avoir trouvé comment ajouter le commentaire avec Mirage OS.

Je poste donc la version finale du jeu et je ne le modifierais plus car je suis déjà sur d'autres projets

Tower Def.gif

Tout est dans le .rar suivez juste bien le readme pour les contrôles un peu difficiles à prendre en main au début.
Je vous souhaite donc bon jeu

[Adriweb]

C'est très joli en tout cas

Je te conseille de le mettre dans les archives de TI-Planet, pour largement augmenter sa visibilité


Edit : je vois que tu l'as fait
Voilà le lien, pour ceux qui se le demandent : https://tiplanet.org/forum/archives_voir.php?id=131662

[Clément.7]

Très joli en effet et ça ressemble à pas mal de Tower Def comme Defend The Bunker et j'en passe c'est très bien fait.
Je télécharge !

EDIT : C'est normal que le titre de la page dans les archives soit "Toxer Def" au lieu de "Tower Def" ?

[Plokki]

EDIT : C'est normal que le titre de la page dans les archives soit "Toxer Def" au lieu de "Tower Def" ?

Comment j'ai pu laisser passer ça ?
En tout cas je suis super content de voir que ça plait

[Clément.7]

On voit que TI-Planet a une communauté de très bon développeurs même autour des z80.
Tower Def est pour moi l'un des meilleurs jeux pour TI-82/83/84+ toutes époques confondues avec Super Smash Bros Open. !
(et vu qu'on a un éditeur de niveaux :crazy:)

[Hayleia]

Bon ben j'en déduis que mon code est irréprochable

Pas du tout, ça veut dire que parmi les 4 personnes qui ont téléchargé, aucune n'a cherché/trouvé/reporté de problèmes.
Mais puisque tu y tiens, j'ai cherché, trouvé et je vais reporter des problèmes

Je mets le code en bas de ce post en référence. Indenté et tout en plus, pas comme celui que tu as fourni
Par contre, la balise code ne met pas de numéros de ligne donc il te faudra copier coller ton code dans un éditeur de texte pour mieux voir de quoi je parle.


Tout d'abord, tes noms de variables ne veulent rien dire.
A, B, Pic2, etc.
Du coup, non seulement je ne comprends rien au code et ne vais donc commenter que les optimisations simples et pas les optimisations algorithmiques, mais en plus tu te mets des bâtons dans les roues pour plus tard car si tu ne bosses plus dessus pendant un moment puis quelqu'un trouve un bug, toi non plus tu ne comprendras rien à ton code. Fais moi confiance, j'ai vécu ça avec Pokemon Topaze, ben je l'ai pas vécu avec Smash grâce à un fichier qui ne contient que des macros. Regarde mes mises à jour, tu verras qu'elles sont très espacées, et pourtant je n'ai jamais eu de problèmes à reprendre mon code.

Pour créer une variable custom, choisis un espace de mémoire libre de 2 octets (regarde du côté de L1, L2, etc).
Fais ensuite un vieux L1→°MaVariable et hop, tu peux faire des MaVariable++ et tout ce que tu veux.
De même, pour avoir un pointeur custom, fais par exemple [0020020000400400]->°MonPointeur et hop, tu peux faire un Pt-On(X,Y,°MonPointeur).


Les lignes 452 et 485 sont à bannir. Oui, même moi, moi qui mets tous les attributs en public quand je code en Java, moi qui met toutes les classes extends dans le même fichier que la classe abstract quand je code en Java, même moi je te dis qu'un Goto et un Lbl dans une boucle For, c'est pas bien.


À la ligne 504, tu fais ça.

Code: Select all

!If {D+1}-1
   10->A
Else!If -1
   10->A
Else!If -1
   20->A
Else!If -1
   25->A
Else!If -1
   60->A
End

Et c'est pas mal. Mais alors pourquoi tu ne fais pas pareil à la ligne 106 avec C ?
Et sinon, si tu veux encore plus abuser d'hl, tu peux faire ça carrément, EN SUPPOSANT que tous les cas soient énumérés sinon, ça ne marchera pas très bien)

Code: Select all

!If {D+1}-1
   10
Else!If -1
   10
Else!If -1
   20
Else!If -1
   25
Else!If -1
   60
End
→A

Et même pire dans le cas présent.

Code: Select all

Data(10,10,20,25,60)→°Lolz
{{D+1}-1+°Lolz}→A

Laisser les parenthèses ouvertes, ça ne fait qu'attirer les bugs. OK, c'est censé marcher, mais ça n'optimise pas le programme compilé et ça fait réfléchir le compilateur plus longtemps. Tu es en revanche excusé si ta calculatrice est une 83+ d'avant 2013 (avec 160 pauvres Ko d'archive).
Pareil pour les guillemets ouverts, mais en plus ça fait foirer mon syntax highlighting donc ça m'énerve encore plus


Si tu utilises un argument dans une fonction qui est égal au précédent, ne l'écris pas.
Exemple: Rect(0,0,J,T) peut devenir Rect(0,,J,T).
Sauve 3 octets dans le cas présent, plus dans d'autres cas.


Un test d'égalité est souvent plus coûteux qu'une soustraction et qu'un test de nullité.
Au lieu de faire K=4?0→{MAP+200} à la ligne 379 par exemple, tu peux faire K-4??0→{MAP+200}.
Et en passant, tu peux encore tuer 3 octets en faisant K-4??→{MAP+200}


Il est plus optimisé de faire

Code: Select all

While 1
EndIf C

que de faire

Code: Select all

Repeat C
End

Ces deux codes ne font pas la même chose, le premier exécute toujours le contenu de la boucle avant de vérifier la condition. Mais dans certains cas (comme l'attente d'une pression sur une touche avec un contenu de boucle vide, comme à la ligne 551), ça ne dérange pas du tout.


Bon, flemme de chercher d'autres problèmes
Le code complet en spoiler, comme dit plus haut.

Show/Hide spoilerAfficher/Masquer le spoiler

Code: Select all

.TOWERDEF
#Axiom(MEMKIT)

Fix 5
DiagnosticOff

[0020020000400400]->Pic2
[0000000000000000]
[000000FFFF000000]
[1818181818181818]
[0000001F1F181818]
[000000F8F8181818]
[1818181F1F000000]
[181818F8F8000000]
[1C3E7FFF7E181818]
[000814227F415545]
[1824428181ADA1FF]
[00003C4281B585FF]
[00103810547C92FE]
[8824428811422411]
[8C4396900969C219]


[C3810000000081C3]->Pic1
[700101018080800E]
[1800008181000018]
[0E80808001010170]
[0E80808001010170]


[0000000000000000]->Pic3
[003C7EDBFFFFFFA5]
[007EFFFF99FFFF5A]
[003C5A7E245A4200]


[0000000000000000]->Pic4
[00245A66665A2400]
[6699A55A5AA59966]
[18203EA5A57C0418]
[003C664242663C00]
[2466DB2424DB6624]

[0040000000000000]->Pic2MAP
[0000000000000000]
[00E0000000000000]
[4040400000000000]
[0060400000000000]
[00C0400000000000]
[4060000000000000]
[40C0000000000000]
[E040400000000000]
[40A0A00000000000]
[40A0A00000000000]
[40A0A00000000000]
[0040E00000000000]
[0040000000000000]
[A040A00000000000]
[A040A00000000000]


ClrDraw
sub(CHARG)
Pause 200

Data(1,2,5,10,17,26,36,49,63,80,1,3,6,12,20,31,43,58,75,95,1,3,7,14,23,35,50,67,87,110)->GDB1W

L1+700->°MAP
UnArchive "appvMAPSTD"
Return!If GtCalc("appvMAPSTD")->MAP
Copy(MAP,L3,768)

0->C->B+1->E
Lbl INIT
Repeat getKey(54)
   C-getKey(4)+getKey(1)->C
   C=~1?4->C
   C=5?0->C
   E-getKey(2)+getKey(3)->E
   E<1?1->E
   E>{MAP+769}?{MAP+769}->E
   ClrDrawDrawInv
   RectI(2,2,60,60
   RectI(64,2,30,60
   For(X,0,19
      MAP+770*2+X+(E-1*700)->theta
      For(Y,0,19
         nib{Y*20+theta}->B
         Pt-On(X*3+2,Y*3+2,B*8+Pic2MAP
      End
   End
   Text(71,6,"PLAY"
   Text(69,15,"SUPPR"
   Text(73,24,"NEW"
   Text(71,33,"EDIT"
   Text(71,42,"QUIT"
   Text(68,52,207>Char
   Text(86,52,5>Char
   Text(75,49,E>Dec
   Text(75,55,{MAP+769}>Dec
   RectI(66,C*9+5,26,9
   DispGraph
End
E-1*350+770+MAP->MAP

If C=1
   GtCalc("appvMAPSTD")->MAP
   If {MAP+769}>1 and (E!=1)
      E-1*350+769->F
      ZthetastepMAP,F,350
      {MAP+769}--
   End
   ClrDrawDispGraph
   Pause 200
   Goto INIT
ElseIf C=2
   GtCalc("appvMAPSTD")->MAP
   {MAP+769}++
   {MAP+769}-1*350+769->F
   !If ZthetamaxMAP,F,350)
      {MAP+769}--
      Goto INIT
   End
   For(theta,1,350
      0->{F+MAP+theta}
   End
   F+1+MAP->MAP
ElseIf C=4
   Fix 4
   ClrHome
   Archive "appvMAPSTD"
   Return
End


0->theta->U->S->B->T
1->Z->N
0->P->Q->X->Y
20->M

C=3?C--
If C=2
   4->B
   100->L
Else!If C
   ClrDrawDispGraph
   Pause 500
   0->N
   Repeat getKey(54)
      DispGraphClrDraw
      Pause 250
      Text(40,20,"EASY"
      Text(37,30,"NORMAL"
      Text(40,40,"HARD"
      RectI(32,18,32,31
      RectI(33,N*10+19,30,9
      N-getKey(4)+getKey(1)->N
      N=3?0->N
      N>3?2->N
   End
   100/(N+1)->L
   N*10->N
End

0->{L2}->{L2-1}
Fill(L2,400
L2->r1
For(A,0,{MAP+200}
   {A*2+MAP+201}->{r1+1}
   {A*2+MAP+202}->{r1+2}
   r1+4->r1
End

Repeat L-1>150
Pause 100

theta^2-getKey(9)+1??theta++
theta++

If S
   !If theta^8
      S--
      Z->{L2+4}
      !If U^10
         theta/8->{L2+3}
      Else
         U-1^3+1->{L2+3}
      End
   End
End
theta>24?0->theta

.MAP
For(W,Q,Q+6
   For(V,P,P+11
      nib{W*10+MAP*2+V}->K
      Pt-On(V-P*8,W-Q*8,K*8+Pic2
   End
End

.MOVEMOB
If inData(theta,Data(4,8,12,16,20,24,0))
   {MAP+200}-1*4+L2+3->r1
   {r1+4}?L-{r1+5}->L
   For(V,0,{MAP+200}
      {r1}->{r1+4}
      {r1++}->{r1+4}
      r1-5->r1
   End
End

.AFFMOB+VIE
L2->r2
For(V,0,{MAP+200}
   If {r2+3}
      {r2+1}-P*8->G
      {r2+2}-Q*8->H
      Pt-On(G,H,{r2+3}*8+Pic3
      Rect(G,H-2,{r2+4}*8/Z,1
   End
   r2+4->r2
End

.AFFTOUR
If T
   6+L1->r1
   For(K,1,T
      {MAP+200}*4+L2->r2
      {r1+2}->G
      {r1+3}->H
      Pt-Off(G-P*8,H-Q*8,{r1+1}*8+Pic4
      sub(ATT
      r1+6->r1
   End
End

.CURSEUR
Pt-On(X*8,Y*8,theta/6*8+Pic1

.MOVECURSEUR
If getKey(1)
   If Q<13 and (Y=3)
      Q++
   ElseIf Y<6
      Y++
   End
ElseIf getKey(4)
   If Q>0 and (Y=3)
      Q--
   ElseIf Y>0
      Y--
   End
End

If getKey(2)
   If P>0 and (X=6)
      P--
   ElseIf X>0
      X--
   End
   ElseIf getKey(3)
      If P<8 and (X=6)
         P++
      ElseIf X<11
         X++
      End
   End
   
   sub(MENU
   
   If B<4
      Rect(0,0,40,8
      RectI(0,0,39,7
      Text(0,0,M>Dec
      Text(12,0,"epsilon"
      Text(20,0,L>Dec
      Text(33,0,"Omega"
   End
   
   DispGraphClrDraw
   If U=31 and (L<101)
      150->L
      Goto WL
   End
   
   If getKey(15)
      Rect(24,16,48,32
      RectI(25,17,46,30
      Text(31,20,"QUITTER ?"
      sub(YN)?160->L
   End
End

Lbl WL
If C-2
   Rect(24,16,48,32
   RectI(25,17,46,30
   If L=150
      Text(30,26,"VICTOIRE !"
   Else
      Text(32,26,"DEFAITE !"
   End
   DispGraph
   Pause 3000
End
GtCalc("appvMAPSTD")->MAP
Goto INIT



Lbl MENU

getKey->K

Copy(B*96+L3,L6+672,96
Line(0,55,95,55

If B=0
   K=54?B++
   Pt-On(1,56,U-1^3+1*8+Pic3
   Text(13,56,S>Dec
   Pt-On(23,56,U^3+1*8+Pic3
   Text(34,56,U/3+2*5>Dec
   If K=49 and (S=0)
      M+U->M
      U++
      U-1^3??{U-1/3+GDB1W+N}->Z
      U-1/3+2*5->S
      !If U^10
         U/10->{L2+7}
         Z*2->{L2+8}
         0->theta
      End
   End
   Text(66,56,U>Dec
ElseIf B=1
   K=55?B--
   If K=53 or (K=52)
      sub(TPOS)?2->B
   ElseIf K=51
      sub(TPOS)?sub(EFFT)
   ElseIf K=50 or (K=49)
      3->B
   End
ElseIf B=2
   K=55?1->B
   
   If (K=53) or (K=52)
      sub(TPOS)
   End
   K=49?sub(UPGD)
   Circle({D+2}-P*8+4,{D+3}-Q*8+4,{D+5}*8
   
   .LVL+DMG
   Text(20,56,{D+6}>Dec
   Text(58,56,{D+4}>Dec
ElseIf B=3
   K=55?1->B
   
   If K<=53 and (K>=49)
      !If nib{Q+Y*10+MAP*2+P+X}+sub(TPOS)
         sub(ADDT)
      End
   End
ElseIf B>3
   If K=54 and (B<7)
      B++
   ElseIf K=55 and (B>4)
      B--
   End
   !If theta^8+N
      1->{L2+3}
   End
   If K<=53 and (K>=49)
      abs(K-54)-1->K
      If B<7
         B-4*5+K->nib{Q+Y*10+MAP*2+P+X}
      ElseIf B=7
         K=4?0->{MAP+200}
         If K=3 and ({MAP+200}>0)
            {MAP+200}--
         End
         K=2?1-N->N
         If K=1 and ({MAP+200}<74)
            {MAP+200}++*2+201+MAP->r1
            P+X->r2->{r1}
            Q+Y->r3->{r1+1}
            {MAP+200}*4+L2+1->r1
            r2->{r1}
            r3->{r1+1}
         End
      End
   End
   If B=7
      Text(6,56,{MAP+200}>Dec
   End
End
Return

Lbl ADDT
abs(K-54)->K
!If K-1
   10->A
Else!If -1
   10->A
Else!If -1
   20->A
Else!If -1
   25->A
Else!If -1
   60->A
End
If A<=M
   If sub(CASH,A)
      M-A->M
      T++
      T*6+L1+1->r3
      K->{r3}
      P+X->{r3+1}
      Q+Y->{r3+2}
      1->{r3+3}
      3->{r3+4}
      If K=4
         2->{r3+4}
      ElseIf K=5
         2->{r3+3}
      End
      1->{r3+5}
   End
End
Return

Lbl TPOS
For(V,1,T
   If P+X={V*6+L1+2} and (Q+Y={V*6+L1+3})
      V*6+L1->D
      1
      Return
   End
End
0
Return


Lbl ATT

For(V,0,{MAP+200}
   If {r2+3}
      If abs(G-{r2+1})+abs(H-{r2+2})<={r1+5}
         
         If ({r1+1}!={r2+3}) and ({r1+1}<4)
            Goto PASS
         End
         
         
         If {r1+1}!=4
            Line(G-P*8+4,H-Q*8+4,{r2+1}-P*8+4,{r2+2}-Q*8+4
         Else
            rand^14->I
            rand^10->J
            Pxl-On(G-P*8+I,H-Q*8-J
            Pxl-On(G-P*8+8+J,H-Q*8+I
            Pxl-On(G-P*8-8+I,H-Q*8+8+J
            Pxl-On(G-P*8-J,H-Q*8+8-I
         End
         
         
         If inData(theta,Data(4,8,12,16,20,24,0))
            {r2+4}-{r1+4}->{r2+4}
            If {r2+4}-1>220
               0->{r2+3}->{r2+4}
               M++
            End
            If {r1+1}=3 and {r2-5}
               Line({r2+1}-P*8+4,{r2+2}-Q*8+4,{r2-7}-P*8+4,{r2-6}-Q*8+4
               {r2-4}-{r1+4}->{r2-4}
               If {r2-4}-1>220
                  0->{r2-5}->{r2-4}
                  M++
               End
            End
         End
         
         ReturnIf {r1+1}<4
Lbl PASS
      End
   End
   r2-4->r2
End
Return


Lbl EFFT
Rect(24,16,48,32
RectI(25,17,46,30
Text(28,20,"SUPPRIMER ?"
Return!If sub(YN)
Copy(D+7,D+1,T*6-D+L1+6
T--
1->B
Return

Lbl UPGD
!If {D+1}-1
   10->A
Else!If -1
   10->A
Else!If -1
   20->A
Else!If -1
   25->A
Else!If -1
   60->A
End
e^({D+6}-1)*A->A
If A<=M and ({D+6}<5)
   If sub(CASH,A)
      M-A->M
      {D+6}++
      If {D+1}-5
         {D+4}*2->{D+4}
      Else
         {D+5}++
         {D+4}++
      End
      If {D+1}=4 and ({D+6}=2)
         {D+4}--
         {D+5}++
      End
      If ({D+1}<4)
         If ({D+6}/2*2-{D+6})
            {D+5}++
         End
      End
   End
End
Return


Lbl CASH
Rect(24,16,48,32
RectI(25,17,46,30
Text(26,20,"PAYER                |E ?"
Text(48,20,r1>Dec
sub(YN)
Return

Lbl YN
Text(28,35,"OUI :1  NON :2"
DispGraph
Repeat getKey(34) or getKey(26)
End
1-getKey(26)
Return

Lbl CHARG
For(A,0,16
   DispGraphClrDraw
   ReturnIf getKey(0)
   Pause 600
   Rect(0,35,96,18
   RectI(0,37,96,14
   Pt-On(A*8,40,Pic3+8
   Pt-On(A-2*8,40,Pic3+16
   Pt-On(A-4*8,40,Pic3+24
   Pt-On(64,24,Pic4+8
   Line(68,28,A*8+4,44
   Text(25,10,"CHARGEMENT"
   For(B,0,A^3
      Text(B*3+65,10,"."
   End
End


[Plokki]

Bon ben j'en déduis que mon code est irréprochable

Pas du tout, ça veut dire que parmi les 4 personnes qui ont téléchargé, aucune n'a cherché/trouvé/reporté de problèmes.
Mais puisque tu y tiens, j'ai cherché, trouvé et je vais reporter des problèmes

J'étais sûr que tu réagirais XD !
En tout cas merci d'avoir pris le temps de regarder mon code j'ai appris pas mal de trucs (pour le coup du lbl et du goto dans la boucle for( je savais pas que c'était pas bien mais c'est pas la peine de me parler du java, j'y connais rien ).
pour ce qui est des parenthèses laissées ouvertes c'est à cause des habitudes de programmation en basic par contre tu te pleins de mon code pas clair et pas aéré, espacé, commenté et tout mais c'est parce que j'utilise l'éditeur de la calculatrice qui est très lent et lui-même pas clair du tout. Du coup je ne veux pas mettre de commentaires qui prennent de la place parce qu'il faut déjà un temps pas possible pour parcourir le code de bout en bout.

Mais ça me donne des idées !
Pourquoi ne pas faire une application qui remplace l'éditeur de programme de la calculatrice ? Avec, bien sûr une meilleure rapidité et une police plus petite pour afficher plus de texte à l'écran. On pourrait aussi rajouter plein de possibilités comme un copier/couper/coller entre programmes et à l'intérieur du programme lui-même, un éditeur de sprites, de tilemap et d'images, une vérification intégrée de la syntaxe, la possibilité de programmer en basic ou en axe, éditer des programmes archivés, etc...
Alors ? Qui s'y colle ?
Si ça existe déjà je tiens à tester

[mdr1]

Mais ça me donne des idées !
Pourquoi ne pas faire une application qui remplace l'éditeur de programme de la calculatrice ? Avec, bien sûr une meilleure rapidité et une police plus petite pour afficher plus de texte à l'écran. On pourrait aussi rajouter plein de possibilités comme un copier/couper/coller entre programmes et à l'intérieur du programme lui-même, un éditeur de sprites, de tilemap et d'images, une vérification intégrée de la syntaxe, la possibilité de programmer en basic ou en axe, éditer des programmes archivés, etc...
Alors ? Qui s'y colle ?
Si ça existe déjà je tiens à tester

Va donc engueuler Xeda qui travaillait sur un éditeur universel pour Basic, Grammer, Axe et peut-être même assembleur : https://www.omnimaga.org/grammer/grammer-3-concepts-ideas-requests/msg387748/#msg387748. Je plaisante, il n'y a presque aucune chance qu'elle le termine un jour.