****************************************************************************
****************************************************************************
**                                                               
**  Platinum Edition for TI-89 (Formation Pattern Processing)
**
**  This software is in the public domain.  There is no warranty.
**
**  by Patrick Davidson (pad@calc.org, http://pad.calc.org/)
**
**  Last updated July 7, 2001
**
****************************************************************************
****************************************************************************

PATTERN MACRO
\1      equ     P_\1-Do_Pattern
        ENDM

Do_Pattern:
        move.w  pattern_type(a5),d0
        jmp     Do_Pattern(pc,d0.w)

P_DONTMOVE:
        rts

        PATTERN DONTMOVE

P_RECTANGLE:
        moveq   #1,d0
        moveq   #31,d1
        lea     pattern_x(a5),a0
        btst    #0,pattern_stage+1(a5)
        beq.s   horiz_motion
        btst    #0,cycle_counter+3(a5)
        bne.s   pattern_done
        addq.w  #2,a0
        moveq   #15,d1
horiz_motion:
        btst    #1,pattern_stage+1(a5)
        beq.s   forward_motion
        moveq   #-1,d0
forward_motion:
        add.w   (a0),d0
        move.w  d0,(a0)
        and.w   d1,d0
        bne.s   pattern_done
        addq.w  #1,pattern_stage(a5)
pattern_done
        rts

        PATTERN RECTANGLE