hl2op:
;in	hl = number
;	ix = place in ram to save output
;del	all(ix = ix+9)
;descr	gemaakt omdat ik deze functie niet kende: SetXXXXOP2
 ld	a, (sign)
 ld	(ix), a;sign
 inc	ix
 
 ;hoeveel getallen hebben we nodig?
 ld	de, 10000;de kan nooit 100000 worden dus moeten eerst ff checken of ie niet meer is dan 10000
 cphlde
 jr	nc, meerdan9999
 
 ld	de, 1
 ld	b, 0;hoeveel getallen we nodig hebben
noggetalmeer:
 push	de;we hebben niet 100 nodig als t getal 9<x<100 is, maar 10, dus vorige getal slaan we telkens op
 call	dex10
 inc	b
 cphlde
 jr	c, zoveelgetallen
 pop	af;junk
 jr	noggetalmeer
meerdan9999:
 ld	b, 5
 push	de
zoveelgetallen:

 
 ld	a, $7f;$80 = 1 getal, $81 = 2 getallen
 add	a, b;a moet op 2e byte van IX
 ld	(ix), a
 inc	ix
 
 ;als b oneven is moet ie alsnog even aantal keer de loop uitvoeren, omdat de getallen nou eenmaal per 2 zijn opgeslagen
 bit	0, b
 jr	z, even
 inc	b
even:
 
 pop	de
 push	bc;zodat we strx ix nog keer wat kunnen doen om ix precies in totaal + 9 te doen
 ;de = het getal waar we um als eerst door gaan delen
 ;hl = het getal
 ;b = hoeevaak we de loop moeten doen(2,4,6)
 
 ;het getal in memory plaatsen in goede formaat
 ld	c, 1;meteen eerste keer getal keer 16(moet namelijk uitkomen $12 $32 voor het getal 1232, en $12 = 1*16+2)
hl2op_loop:
 push	de
 call	hldivde
 dec	c
 jr	z, welkeer16
 ld	a, (ix)
 add	a, l
 ld	(ix), a
 inc	ix
 jr	welkeer16_
welkeer16:
 ld	c, 2;zodat volgende keer c niet weer 0 is
 ld	a, l
 add	a, a;x2
 add	a, a;x4
 add	a, a;x8
 add	a, a;x16
 ld	(ix), a;komt strx nog wat bij
 
welkeer16_:
 ex	de, hl
 
 pop	de
 push	hl
 ex	de, hl
 ld	d, 10
 call	hldivd
 ld	de, 0
 cphlde
 jr	nz, nietzero
 ld	hl, 1;alles behalve 0, anders gaat ie zometeen hl delen door 0 en dat geeft problemen
nietzero:
 ex	de, hl
 pop	hl;de=de/10
 
 djnz	hl2op_loop
 
 
 ;ix moet precies plus negen, dat doen we hier
 pop	bc
 srl	b;b=b/2
 ld	a, 7;totaal wat ix nog moet
 sub	b;min dit
 ld	b, a
ixplus:
 inc	ix
 djnz	ixplus
 ret