;/////////////
;/// INTRO ///
;/////////////

Intro:
 bcall(_cleargbuf)
    ld a,24
    ld (ActualContrast),a
    or $C0
    out (LCDINSTPORT),a ;Bright

    
 ld de,28*256+16
 ld hl,TitleTxt    
 call LightUp
    
    
    ld de,28*256+30
    ld hl,IntroText1 ;Powered

    call LightUp ;incl. FastCopy
    
    
    ld de,28*256+40
    ld hl,IntroText2 ;by
    
    call LightUp ;by
    
    ld a,(StartContrast)
    or $C0
    out (LCDINSTPORT),a
   
    ld b,4
IntroHeadLoop:
    push bc
    call HeadFlicker
    pop bc
    djnz IntroHeadLoop

    ld bc,768
    ld de,plotsscreen
    ld hl,IntroPic
    ldir
    call _IonFastCopy
    call IntroWait2
    call IntroWait2
    
    ld a,(StartContrast)
    ld (ActualContrast),a
    ld (ContrastToGetTo),a
    ld a,$3D
    ld (ContrastChangeOP),a    ; glaub nicht nötig
    
    
    jr IntroEnd
    
    
LightUp:
    call DispVText

    call _IonFastCopy
    ld hl,StartContrast
    ld de,ActualContrast
    
LightUpLoop:    
    call IntroWait
    ld a,(de)
    inc a
    cp (hl)
    jr nc,LightDownLoop
    ld (de),a
    or $C0
    out (LCDINSTPORT),a
    jr LightUpLoop
LightDownLoop:
    call IntroWait
    ld a,(de)
    dec a
    cp 25
    jr z,LightDownOK
    ld (de),a
    or $C0
    out (LCDINSTPORT),a
    jr LightDownLoop
LightDownOK:
    bcall(_cleargbuf)
    ret
  
HeadFlicker:
 bcall(_cleargbuf)
    ld bc,612
    ld de,plotsscreen
    ld hl,IntroPic
    ldir
    
    ld hl,plotsscreen+611
    ld bc,768-612
    ldir
    
    call _IonFastCopy

    call IntroWait2
            
 bcall(_cleargbuf)    
    call _IonFastCopy
   
    call IntroWait2
    
    ret
    
IntroWait2:
    ld bc,60000
    jr IntroWaitLoop
IntroWait:
    ld bc,10000
IntroWaitLoop:
    dec bc
    ld a,c
    or b
    jr nz,IntroWaitLoop
    ret
    
IntroEnd: